acms/frontend/app/Route.hs

module Route
  ( Route (..),
    parseURI,
    routeToString,
  )
where

import Data.Attoparsec.Text qualified as P
import Data.Default
import Data.Text qualified as T
import Miso

data Route
  = Home
  | ListCollection String
  | EditValue String String
  | NewCollection
  deriving (Show, Eq)

instance Default Route where
  def = Home

parseURI :: URI -> Route
parseURI uri =
  either (const def) id $
    P.parseOnly
      ( P.choice
          [ EditValue
              <$> (P.string "#collection/" *> P.manyTill P.anyChar (P.string "/"))
              <*> (P.many1 P.anyChar),
            pure NewCollection <* (P.string "#collection/new"),
            ListCollection <$> (P.string "#collection/" *> P.many1 P.anyChar),
            pure Home
          ]
          <* P.endOfInput
      )
      (T.pack uri.uriFragment)

routeToString :: Route -> String
routeToString Home = "#"
routeToString (ListCollection collection) = "#collection/" <> collection
routeToString (EditValue collection fileName) = "#collection/" <> collection <> "/" <> fileName
routeToString NewCollection = "#collection/new"