MASSIVE restructuring

modules/retiolum.nix

@@ -0,0 +1,72 @@
+{ config, pkgs, lib, ... }:
+with lib;
+let
+  netname = "retiolum";
+  cfg = config.networking.retiolum;
+in {
+  options = {
+    networking.retiolum.ipv4 = mkOption {
+      type = types.str;
+      description = ''
+        own ipv4 address
+      '';
+    };
+    networking.retiolum.ipv6 = mkOption {
+      type = types.str;
+      description = ''
+        own ipv6 address
+      '';
+    };
+    networking.retiolum.nodename = mkOption {
+      type = types.str;
+      default = config.networking.hostName;
+      description = ''
+        tinc network name
+      '';
+    };
+  };
+  config = {
+    services.tinc.networks.${netname} = {
+      name = cfg.nodename;
+      extraConfig = ''
+        LocalDiscovery = yes
+        ConnectTo = gum
+        ConnectTo = ni
+        ConnectTo = prism
+        ConnectTo = eve
+        AutoConnect = yes
+      '';
+    };
+
+    networking.extraHosts = builtins.readFile (pkgs.fetchurl {
+      name = "retiolum.hosts";
+      url = "https://lassul.us/retiolum.hosts";
+      # FIXME
+      sha256 = "0q8f5gw12hf9dhwcs4fni8jrvb2a1g6jskz28qcbd10p2xlkja58";
+    });
+
+    environment.systemPackages = [ config.services.tinc.networks.${netname}.package ];
+
+    systemd.services."tinc.${netname}" = {
+      path = with pkgs; [ curl gnutar bzip2 ];
+      preStart = ''
+        curl https://lassul.us/retiolum-hosts.tar.bz2 | tar -xjvf - -C /etc/tinc/${netname}/ || true
+      '';
+    };
+
+    networking.firewall.allowedTCPPorts = [ 655 ];
+    networking.firewall.allowedUDPPorts = [ 655 ];
+
+    systemd.network.enable = true;
+    systemd.network.networks = {
+      "${netname}".extraConfig = ''
+        [Match]
+        Name = tinc.${netname}
+        [Network]
+        Address=${cfg.ipv4}/12
+        Address=${cfg.ipv6}/16
+      '';
+    };
+  };
+
+}